Cоздаем эффект вибрации/дрожи/тряски объекта

import flash.utils.setTimeout;
import flash.utils.Timer;
import flash.geom.Point;
import flash.events.Event;

var text_variants:Array = ['1 вариант текста','2 вариант текста','3 вариант текста','4 вариант текста'];
//варианты значений текстового поля
var tf_position:Point;
//Point содержит в себе координаты чего-либо(текстового поля), полезно, т.к. нет необходимости создавать две переменные
var now_index:Number = -1;
//последний индекс в массиве вариантов, нужен для защиты от повторения значения
var effect_power:Number = 1;
//насколько сильно объект будет "улетать" от своей текущей позиции
var update_delay:Number = 4;
//время задержки перед следующим обновлением значения текстового поля в секундах

initStage();
function initStage():void
{//инициализирует сцену
 
	tf_position = new Point(vibratto_txt.x,vibratto_txt.y);
	//запоминаем текущие координаты
	stage.addEventListener(Event.ENTER_FRAME, updateTfPosition);
	//24 раза в секунду возвращаем текстовое поле на место
	updateTfValue();
	//запускаем цикл обновлений и заодно обновляем значение
}

function updateTfPosition(e:Event):void
{//Эта функция возвращает текстовое поле на место
 
	vibratto_txt.x = tf_position.x;
	//присваем координату из памяти по х
	vibratto_txt.y = tf_position.y;
	//присваем координату из памяти по y
}

function updateTfValue():void
{//Эта функция обновляет содержимое текстового поля
 
	var timer:Timer = new Timer(20,21);
	//создаем таймер длительностью 20 милисекунд, повторить 21 раз
	/*
	   таймер через каждые 20 милисекунд будет трясти текстовое поле
	   после 21 повторения эффекта тряски он перестанет работать
	*/
	timer.addEventListener(TimerEvent.TIMER, shakeTf);
	//каждый раз(пока идет повторение) вызываем эффект дрожи
 
	var random_index:Number = Math.floor(Math.random() * text_variants.length);
	//выбираем случайную ячейку массива
	if (random_index != now_index)
	{//если это не та ячейка, что была в прошлый раз, то запускаем таймер
 
		timer.start();
		//запускаем таймер
		setTimeout(updateTfValue, update_delay * 1000);
		//запускаем таймер, по истечении которого эта функция вызовется еще раз(изменится значение текстового поля)
		vibratto_txt.text = text_variants[random_index];
		//указываем текстовому полю значение той ячейки, что сгенерировали
		now_index = random_index;
		//запоминаем текущую ячейку
	}
	else
	{//если та ячейка, что была в прошлый раз, то повторяем генерацию случайной ячейки еще раз
 
		updateTfValue();
	}
}

function shakeTf(e:Event):void
{//Эта функция отвечает за анимацию дрожи
 
	var rand:Number = Math.random();
	//генерируем число от 0 до 1
	if (rand >= 0.5)
	{//если число больше 0.5, то перемещаем вправо и вниз
 
		vibratto_txt.x +=  Math.random() * effect_power;//на расстояние от 0 до 1 пиксела
		vibratto_txt.y +=  Math.random() * effect_power;
	}
	else
	{//если нет, то вверх и влево
 
		vibratto_txt.x -=  Math.random() * effect_power;
		vibratto_txt.y -=  Math.random() * effect_power;
	}
}